*****************************************************************
* INFINEON TECHNOLOGIES                                         *
* BCR400R / BCR400W SPICE2G6 MODEL                              *
* Version: 1.1                                                  *
* Date: 2000-01-07                                              *
* Author: J.P. Schaffer                                         *
*****************************************************************
* SPICE2G6 MODEL OF THE PNP BIPOLAR TRANSISTOR IN BCR400        *
*****************************************************************
.MODEL TI400 PNP (
+ IS=14.0F NF=1.00 BF=400 VAF=43.0 IKF=0.180
+ ISE=12.5F NE=2.234 NR=1.005 BR=4.80 VAR=6.96 IKR=0.466
+ ISC=62.5F NC=2.074
+ RB=4.40 IRB=0.050M RBM=3.00
+ RE=0.60 RC=4.50
+ CJE=5.90P VJE=1.00 MJE=0.435 FC=0.750
+ CJC=4.35P VJC=0.900 MJC=0.600 XCJC=0.650
+ TF=0.600N TR=2.604N PTF=1.00
+ XTF=6.500 VTF=2.000 ITF=0.157
+ XTB=1.60 EG=1.110 XTI=3.30
+ KF=5.00F AF=1.00)
*****************************************************************
* SPICE2G6 MODEL OF INTERNAL DIODE IN BCR400                    *
*****************************************************************
.MODEL DI400 D(
+ IS=6.0E-15 N=1.20E+00 RS=5.0E+01
+ IBV=1.00E-04 BV=7.5E+01
+ M=1.00E-01 CJO=6.87E-13 EG=1.11E+00
+ TT=8.66E-09 VJ=2.00E+00 XTI=5.0E+00)
*****************************************************************
* RESISTORS                                                     *
*****************************************************************
.MODEL RDMOD R (TC1=1.706E-3 TC2=8.92E-6)
*****************************************************************
* Circuit:                                                      *
* Nodes 1, 2, 3, 4, correspond to repective pin numbers         *
*****************************************************************
.subckt BCR400R 1 2 3 4
RINT  3  4     6.50k RDMOD
RB   10  1     65.0k RDMOD
D1    3 30     DI400
D2   30 10     DI400
Q1    2 10  4  TI400
.ends BCR400R