*****************************************************************
* INFINEON TECHNOLOGIES                                         *
* BCR401R BCR402R BCR401W BCR402W SPICE2G6 MODEL                *
* Version: 1.2                                                  *
* Date: 2007-07-25                                              *
* Author: J.P. Schaffer                                         *
*****************************************************************
* SPICE2G6 MODEL OF THE PNP BIPOLAR TRANSISTOR IN BCR401R       *
*****************************************************************
.MODEL T0295 PNP (
+ IS=28.000F NF=1.000 BF=330 VAF=43.000 IKF=0.380
+ ISE=24.903F NE=2.234 NR=1.005 BR=4.800 VAR=6.960 IKR=0.932
+ ISC=0.125P NC=2.074
+ RB=2.200 IRB=0.100M RBM=1.500
+ RE=0.300 RC=2.251
+ CJE=60P VJE=1.000 MJE=0.435 FC=0.750
+ CJC=30P VJC=0.900 MJC=0.600 XCJC=0.650
+ TF=0.600N TR=2.604N PTF=1.000
+ XTF=6.500 VTF=2.000 ITF=0.314
+ XTB=1.600 EG=1.110 XTI=3.300
+ KF=5.000F AF=1.000)
*****************************************************************
* SPICE2G6 MODEL OF INTERNAL DIODE IN BCR401R                   *
*****************************************************************
.MODEL DI400 D(
+ IS=6.0E-15 N=1.20E+00 RS=5.0E+01
+ IBV=1.00E-04 BV=7.5E+01
+ M=1.00E-01 CJO=6.87E-13 EG=1.11E+00
+ TT=8.66E-09 VJ=2.00E+00 XTI=5.0E+00)
*****************************************************************
* RESISTORS                                                     *
*****************************************************************
.MODEL RDMOD R (TC1=-1.40E-3 TC2=5.19E-6)
.MODEL RPMOD R (TC1=1.20E-3 TC2=8.58E-6)
*****************************************************************
* Attention! Pspice refuses 'R'                                 *
* model cards, comment above .MODEL                             *
* statement and                                                 *
* replace all 'RDMOD'-calls by:                                 *
* TC=-1.40E-3,5.19E-6                                           *
* replace all 'RPMOD'-calls by:                                 *
* TC=1.20E-3,8.58E-6                                            *
*                                                               *
*****************************************************************
* Circuit: BCR401R                                              *
* Nodes 1, 2, 3, 4, correspond to repective pin numbers         *
*****************************************************************
.subckt BCR401R 1 2 3 4
RINT  3  4     85    RDMOD
RB   10  1     27.0k RPMOD
D1    3 30     DI400
D2   30 10     DI400
Q1    2 10  4  T0295
.ends BCR401R
*****************************************************************
* Circuit: BCR402R                                              *
* Nodes 1, 2, 3, 4, correspond to repective pin numbers         *
*****************************************************************
.subckt BCR402R 1 2 3 4
RINT  3  4     41    RDMOD
RB   10  1     27.0k RPMOD
D1    3 30     DI400
D2   30 10     DI400
Q1    2 10  4  T0295
.ends BCR402R
*****************************************************************
* Circuit: BCR401W                                              *
* Nodes 1, 2, 3, 4, correspond to repective pin numbers         *
*****************************************************************
.subckt BCR401W 1 2 3 4
RINT  3  4     85    RDMOD
RB   10  1     27.0k RPMOD
D1    3 30     DI400
D2   30 10     DI400
Q1    2 10  4  T0295
.ends BCR401W
*****************************************************************
* Circuit: BCR402W                                              *
* Nodes 1, 2, 3, 4, correspond to repective pin numbers         *
*****************************************************************
.subckt BCR402W 1 2 3 4
RINT  3  4     41    RDMOD
RB   10  1     27.0k RPMOD
D1    3 30     DI400
D2   30 10     DI400
Q1    2 10  4  T0295
.ends BCR402W