*****************************************************************
* INFINEON TECHNOLOGIES                                         *
* BCR205W SPICE2G6 MODEL                                        *
* Version: 1.0                                                  *
* Date: 2011-06-20                                              *
* Author: J.P. Schaffer                                         *
*****************************************************************
*
*****************************************************************
* Element Models                                                *
*****************************************************************
*****************************************************************
.MODEL N1BT NPN(
+IS=50E-18 BF=120 NF=1.021 VAF=120
+RB=150 IRB=32.5E-6 RE=1.47 RC=150
+EG=1.154
+CJE=99.3E-15 VJE=0.64 MJE=0.3
+CJC=57.6E-15 VJC=0.43 MJC=0.31 FC=0.7
+CJS=247E-15 VJS=0.56 MJS=0.4
+TF=47E-12 TR=72E-9)
*****************************************************************
.MODEL PT62 PNP(
+IS=148E-18 BF=70 NF=1.087 VAF=70
+RB=54 IRB=0 RE=18 RC=462
+EG=1.145
+CJE=48.3E-15 VJE=0.7 MJE=0.2
+CJC=195E-15 VJC=0.62 MJC=0.36 FC=0.7
+TF=22.4E-12 TR=30E-9)
*****************************************************************
.MODEL RPLMOD R (RSH=1000 TC1=-10.5E-4 TC2=3.5E-6)
*****************************************************************
*
*****************************************************************
* Subcircuit BCR205W                                            *
* Nodes 1, 2, 3, 4, correspond to respective pin numbers        *
* 1 = Vs / 2 = GND / 3 = Iout / 4 = Sense                       *
*****************************************************************
.subckt BCR205W 1 2 3 4
* Package Inductance
L1    1 100  0.8n
L2    2 200  0.8n
L3    3 300  0.8n
L4    4 400  0.8n
* Current Source
Q0   10  20  30  N1BT
Q1   20  20  40  N1BT
Q2   40  40 200  N1BT
Q3   10  10 100  PT62
R1      100  20   68k RPLMOD
R2       30 200   22k RPLMOD
* Voltage Reference
Q10 200  10 120  PT62 AREA 5.0
R10     100 120  6.8k RPLMOD
* Output Amplifier
R40 100 400  12K RPLMOD
Q40 430  10 400  PT62
Q41 430 430 200  N1BT
Q42 450 430 200  N1BT AREA 2.0
Q43 300 450 100  PT62 AREA 2.0
.ends BCR205W