*****************************************************************
* INFINEON TECHNOLOGIES                                         *
* BCR401U BCR402U BCR405U SPICE2G6 MODEL                        *
* Version: 1.0                                                  *
* Date: 2008-04-18                                              *
* Author: J.P. Schaffer                                         *
*****************************************************************
* SPICE2G6 MODEL OF THE PNP BIPOLAR TRANSISTOR IN BCR401U       *
*****************************************************************
.MODEL T0305 PNP (
+ IS=100.000F NF=0.995 BF=440 VAF=44.000 IKF=0.07
+ ISE=25F NE=2.234 NR=1.005 BR=4.800 VAR=6.960 IKR=0.932
+ ISC=0.125P NC=2.074
+ RB=4.00 IRB=1 RBM=2.0
+ RE=0.800 RC=1.6
+ CJE=11.800P VJE=1.000 MJE=0.435 FC=0.750
+ CJC=8.700P VJC=0.900 MJC=0.600 XCJC=0.650
+ TF=0.600N TR=2.604N PTF=1.000
+ XTF=6.500 VTF=2.000 ITF=0.314
+ XTB=1.600 EG=1.110 XTI=3.300
+ KF=5.000F AF=1.000)
*****************************************************************
* SPICE2G6 MODEL OF INTERNAL DIODE IN BCR401U                   *
*****************************************************************
.MODEL D0305 D(
+ IS=2.4E-16 N=1.08 RS=1.9
+ IBV=1.00E-04 BV=7.5E+01
+ M=1.00E-01 CJO=1E-14 EG=1.11E+00
+ TT=8.66E-09 VJ=2.00E+00 XTI=5.0E+00)
*****************************************************************
* Circuit: BCR401U                                              *
* Nodes 1, 2, 3, 4, 5, 6 correspond to repective pin numbers    *
*****************************************************************
.subckt BCR401U 1 2 3 4 5 6
RINT  4  6     90    TC1=-1.40E-3 TC2=5.19E-6
RB   10  1     22.0k TC1=1.20E-3 TC2=8.6E-6
D1    4 30     D0305
D2   30 10     D0305
Q1   20 10  6  T0305
R1   20  2     0.01
R2   20  3     0.01
R3   20  5     0.01
.ends BCR401U
*****************************************************************
* Circuit: BCR402U                                              *
* Nodes 1, 2, 3, 4, 5, 6 correspond to repective pin numbers    *
*****************************************************************
.subckt BCR402U 1 2 3 4 5 6
RINT  4  6     43    TC1=-1.40E-3 TC2=5.19E-6
RB   10  1     22.0k TC1=1.20E-3 TC2=8.6E-6
D1    4 30     D0305
D2   30 10     D0305
Q1   20 10  6  T0305
R1   20  2     0.01
R2   20  3     0.01
R3   20  5     0.01
.ends BCR402U
*****************************************************************
* Circuit: BCR405U                                              *
* Nodes 1, 2, 3, 4, 5, 6 correspond to repective pin numbers    *
*****************************************************************
.subckt BCR405U 1 2 3 4 5 6
RINT  4  6     16  TC1=-1.40E-3 TC2=5.19E-6
RB   10  1     22.0k TC1=1.20E-3 TC2=8.6E-6
D1    4 30     D0305
D2   30 10     D0305
Q1   20 10  6  T0305
R1   20  2     0.01
R2   20  3     0.01
R3   20  5     0.01
.ends BCR405U